Einiges zur Laplace -Transformation, FS 2013,  W.Quapp

Integrate[Exp[-s t] ,{t,0,Infinity}]

LaplaceTransform[1,t,s]

liste1={(e^(a t)) , (e^(-3t  )), (e^(5t)) }

Map[LaplaceTransform[#,t,s]&,liste1] /. Log[e]-> 1

Clear[f]

f[t_]:=-1 /; 0≤ t < 4
f[t_]:=1 /; 4≤ t

Plot[f[t],{t,0,8},PlotStyle->Thick]

LaplaceTransform[f[t],t,s]

(* d.h. die 'zweifach' - definierte Funktion f kann LaplaceTransform nicht bearbeiten, Ausweg: *)

Clear[f]
f[t_]:=UnitStep[t-4]-UnitStep[4-t]

LaplaceTransform[f[t],t,s]

((E^(-4 s))/s)-((1-(E^(-4 s)))/s)

liste2={(t^3), Sin[a t], Cos[a t]}

Map[LaplaceTransform[#,t,s]&,liste2]

(*  Shift - Eigenschaft *)

LaplaceTransform[Exp[-2 t] Cos[t],t,s]

Clear[f]

ablei=Table[D[f[t],{t,n}],{n,1,5}]

Map[LaplaceTransform[#,t,s]&,ablei]

LaplaceTransform[(t^n),t,s]

Clear[f]
f[t_]:=(((3 t-1))^3)

LaplaceTransform[f[t],t,s]

LaplaceTransform[f'[t],t,s]

Clear[f,a,k,n]

Liste={1,(t^n),(e^(a t)) , Sin[k t], Cos[k t],Sinh[k t], Cosh[k t],(t^n)(e^(a t)) ,
 Exp[a t] Sin[k t], Exp[a t]  Cos[k t], Exp[a t] Sinh[k t], Exp[a t] Cosh[k t],DiracDelta''[t],DiracDelta '[t],DiracDelta[t]}

Map[{#,LaplaceTransform[#,t,s]}&,Liste]/.Log[e]->1 // TableForm

InverseLaplaceTransform[2/(s^2+4),s,t]

s1=InverseLaplaceTransform[2/(s^2+2 s+5),s,t]

ExpToTrig[s1 ] // FullSimplify

(*  DGl mit LaplaceTransform *)

step1=LaplaceTransform[y'[t]-4 y[t]== Exp[4 t],t,s]

step2=step1 /. y[0]-> 0

step3=Solve[step2,LaplaceTransform[y[t],t,s]]

solution=InverseLaplaceTransform[step3[[1,1,2]],s,t]

(*  waere hier auch leicht mit DSolve ... gegangen !! *)

Plot[solution,{t,0,0.3}]

(* Der Plot zeigt, dass die AW erfuellt sind *)

(* next *)

step1=LaplaceTransform[y''[t]+4 y[t]== Exp[-t] Cos [2 t],t,s]

step2=step1 /. {y[0]-> 0, y'[0]-> -1}

step3=Solve[step2,LaplaceTransform[y[t],t,s]]

solution=InverseLaplaceTransform[step3[[1,1,2]],s,t] //Expand

Plot[solution,{t,0,2 Pi}]

(* Der Plot zeigt wieder, dass die AW erfuellt sind *)

(* next -- komplizierteres Beispiel aus Mma-Hilfe *)

step1=LaplaceTransform[y'''[t]-5 y''[t]+9 y'[t]-5 y[t]== DiracDelta''[t]+2 DiracDelta '[t]+DiracDelta[t],t,s]

step2=step1 /. {y[0]-> 0, y'[0]-> 0,y''[0]->0}// FullSimplify

step3=Solve[step2,LaplaceTransform[y[t],t,s]]// ExpandDenominator

solution=InverseLaplaceTransform[step3[[1,1,2]],s,t] // FullSimplify

Plot[solution,{t,0.0,0.2},PlotRange->All,PlotStyle->Thick,AxesLabel->{"t",y},AxesOrigin->{0,0}]

(*  Vergleich, man beachte, dass AW an der Stelle 0 nicht funktionieren: *)

Clear[y]
loes2=DSolve[y'''[t]-5 y''[t]+9 y'[t]-5 y[t]== DiracDelta''[t]+2 DiracDelta '[t]+DiracDelta[t]&&y[-1]==0&& y'[-1]==0&&y''[-1]==0,y[t],t] // FullSimplify

(*   Die AW und die DeltaFunktionen stoeren sich so nicht gegenseitig.
Weil:  AW wurden 'zurueckverlegt'.
  y≡0 wuerde ueberall eine Loesung sein, wenn nicht die Deltas einen Ruck bei t=0 erzeugen wuerden.  *)

Plot[loes2[[1,1,2]],{t,-0.1,0.23},PlotRange->All,PlotStyle->Thick,AxesLabel->{"t",y}]

Plot[{solution,y[t] /. loes2},{t,-0.1,0.1},PlotLegends->"Expressions"]

(*  Die Laplacetransformation geht ab t,s >0 los , wenn man die LaplaceLoesung fuer <0 einsetzt, gibt es einen falschen Eindruck. Mit DSolve wird die korrekte Loesung mit einem Sprung angegeben. Fuer t>0 stimmen beide Loesungen ueberein. *)