(*  Graphics Complexes:  WQ,  FS 2013 *)

gc=GraphicsComplex[{{1.2,3.5},{5.6,7.2}},{{Red,Point[1],Point[2]},Line[{1,2}]}]

Graphics[{Blue,PointSize[0.05],Thick,gc}]

v={{1,0},{0,1},{-1,0},{0,-1}};

{Graphics[GraphicsComplex[v,Polygon[{1,2,3,4}]]],Graphics[GraphicsComplex[v,Line[{1,2,3,4,1}]]]}

v={{0,0,0},{2,0,0},{2,2,0},{0,2,0},{1,1,2}};
i={{1,2,5},{2,3,5},{3,4,5},{4,1,5}};

{Graphics3D[{Opacity[.8],Yellow,GraphicsComplex[v,Polygon[i]]}],Graphics3D[{Thick,GraphicsComplex[v,Line[i]]}]}

Use built-in PolyhedronData:

v=PolyhedronData["Dodecahedron","VertexCoordinates"];
Short[i=PolyhedronData["Dodecahedron","FaceIndices"]]

{Graphics3D[{Yellow,GraphicsComplex[v,Polygon[i]]}],
Graphics3D[{Thick,GraphicsComplex[v,Line[i]]}]}

PolyhedronData[]

platoKoerp=PolyhedronData["Platonic"]

PolyhedronData["Cube","Properties"]

cube=PolyhedronData["Cube","Faces"]

octa=PolyhedronData["Octahedron","Faces"]

Graphics3D[{cube,octa}]

radii={#,PolyhedronData[#,"Inradius"],PolyhedronData[#,"Circumradius"]}& /@platoKoerp;
Text@Grid[Prepend[radii,{"Körper","Inkugelradius","Umkugelradius"}],Dividers->{{{True}},{True,True,{False},True}},Spacings->{1,2}]

(* Setze verkleinertes Octahedron in durchsichtigen Würfel *)

trans[t_,g_GraphicsComplex]:=GraphicsComplex[(DiagonalMatrix[{t,t,t}].#&) /@ g[[1]],g[[2]] ]

trans[1/Sqrt[2], octa]

Graphics3D[{{Yellow,Opacity[0.3],cube},
{Green,trans[1/Sqrt[2], octa]}},PlotRange->All,Boxed->False,Lighting->{White}]

(* Verbinde Graphics und Numerik: Flaeche zwischen 2 Kurven *)

f=Sin[x+1];
g=x^3- 3 x +1;
zweiKurven=Plot[{f,g},{x,-3,3},PlotStyle->{{},Thick}]

x1= x /. FindRoot[f==g,{x,-2}]
x2= x /. FindRoot[f==g,{x, 0}]
x3= x /. FindRoot[f==g,{x, 2}]

(* Wir wollen das Gebiet straffieren *)

Plot[{f,g},{x,-3,3},PlotStyle->{{},Thick},Filling->{1->{2}}]

(* mit selbstgestrickter Schraffur *)
Show[zweiKurven,Table[Graphics[Line[{{x,f},{x,g}}]],{x,x1,x3,0.2}]]

(* Nun die Integration *)

links=Integrate[1,{x,x1,x2},{y,f,g}]

rechts=Integrate[1,{x,x2,x3},{y,g,f}]

flaeche= rechts + links

(* Kontrolle *)

NIntegrate [Abs[f-g],{x,x1,x3}]